VBScript
El ejemplo siguiente muestra cómo utilizar código VB Script para generar un archivo RTF de salida utilizando un archivo PXF y un archivo XML de entrada. Asegúrese de que StyleVision Server está instalado y tiene licencia, y de que está disponible como objeto de servidor COM. El registro como objeto de servidor COM suele hacerse durante la instalación de StyleVision Server. Para comprobar si el registro se ha realizado correctamente, consulte Información sobre la interfaz COM.
Option Explicit
'Cree un objeto StyleVision Server; utilice «StyleVision_x64.Server» si desea utilizar la instalación de 64 bits.
Dim objSVS
' Dado que cargamos un COM-DLL, debemos tener cuidado con la arquitectura del proceso.
On Error Resume Next ' ignora cualquier error COM evitando la terminación incontrolada del script
Dim WshShell
Dim WshProcEnv
Set WshShell = CreateObject("WScript.Shell")
Set WshProcEnv = WshShell.Environment("Process")
Dim process_architecture
process_architecture= WshProcEnv("PROCESSOR_ARCHITECTURE")
If process_architecture = "x86" Then
Set objSVS = WScript.GetObject( "", "StyleVision.Server" )
If Err.Number <> 0 then
WScript.Echo("Está ejecutando un proceso de 32 bits, pero StyleVision Server COM-API de 32 bits no parece estar instalado en su sistema.")
WScript.Quit -1
End If
Else
Set objSVS = WScript.GetObject( "", "StyleVision_x64.Server" )
If Err.Number <> 0 then
WScript.Echo("Está ejecutando un proceso de 64 bits, pero StyleVision Server COM-API de 64 bits no parece estar instalado en su sistema.")
WScript.Echo("Si ha instalado StyleVision Server de 32 bits, considere la posibilidad de llamar al script desde la consola de 32 bits 'C:\Windows\SysWOW64\cmd.exe.'")
WScript.Quit -1
End If
End If
On Error Goto 0 ' reactivar la promoción de errores predeterminada
'Establezca un directorio de trabajo, que se utilizará para la entrada, la salida y los archivos intermedios».
'objSVS.WorkingDirectory = "C:\Archivos de programa (x86)\Altova\StyleVisionServer2020\etc\examples"
objSVS.WorkingDirectory = ".."
'La ruta predeterminada al ejecutable de StyleVision Server es la ruta de instalación (el mismo directorio que StyleVisionServer.dll).
'En caso de que haya movido los archivos binarios en el disco, debe establecer explícitamente la ruta al archivo .exe.
'La propiedad ServerPath debe configurarse antes que cualquier otra propiedad, ya que reinicializa el servidor y restablece todas las propiedades.
'objSVS.ServerPath = "C:\Archivos de programa (x86)\Altova\StyleVisionServer2020\bin\StyleVisionServer_DebugDLL.exe"
' El método Generate devolverá True si la generación se ha realizado correctamente; en caso contrario, devolverá False.
' En caso de errores fundamentales, como la finalización del proceso del servidor, se generará un error COM que
' se puede gestionar mediante el objeto Err de VBScript.
On Error Resume Next ' ignora cualquier error COM evitando la terminación incontrolada del script
Err.Clear
WScript.Echo("Running " & objSVS.ProductNameAndVersion & vbCrlf)
'Prepare el nombre del XML de trabajo.
' Puede ser una ruta absoluta/relativa si el archivo está almacenado externamente (no dentro de PXF).
' objSVS.InputXML = "ExpReport.xml"
' o puede contener la ruta DENTRO del PXF.
objSVS.InputXML = "ExpReport.pxf|zip\ExpReport.xml"
' o hacer referencia al archivo como incrustado en el archivo de transformación
'objSVS.InputXML = "altova://packagedfile/ExpReport.xml"
'Añada rutas de salida (absolutas o relativas a DirectorioDeTrabajo) para todos los formatos que deban generarse.
' Asegúrese de que tiene permisos de escritura.
'objSVS.OutputRTF = "C:\tmp\ExpReport.rtf"
objSVS.OutputPDF = "C:\tmp\ExpReport.pdf"
'objSVS.OutputHTML = "C:\tmp\ExpReport.html"
'Prepare los parámetros, si su diseño utiliza parámetros.
'Llame a objSVS.AddParameter( "testparam1", "value_1" )
' Ejecute la transformación. La ruta del archivo PXF puede ser relativa a la carpeta de trabajo o absoluta.
WScript.Echo("Generando salida desde ExpReport.pxf...")
If ( objSVS.Generate( "ExpReport.pxf" ) ) Then
WScript.Echo( objSVS.LastExecutionMessage )
WScript.Echo( "La ejecución ha finalizado correctamente" )
Else
WScript.Echo( objSVS.LastExecutionMessage )
End If
' handle COM errors
If Err.Number <> 0 Then
WScript.Echo("Error interno - " & Err.Description )
WScript.Quit -1
End If
On Error Goto 0 ' reactivar la promoción de errores predeterminada