>Archive Index
>xsl-list Archive Home
>Recent entries

>Thread Prev - [xsl] Using XSL to create interactive web page from XML
[Thread Next]

Re: [xsl] Using XSL to create interactive web page from XML

From: Martin Honnen <Martin.Honnen@------>
To:
Date: 12/1/2007 2:24:00 PM

Furst, Tom wrote:



Using XSLT 2.0 is not required.  But if it will make resolving this
problem any easier to accomplish, or for me to understand, I'm all
for it.

If you want to display details in a separate iframe then you need to 
generate additional result documents to be displayed in the iframe. For 
that you need to use xsl:result-document which is only supported in XSLT 
2.0. (Or you would need to use XSLT 1.0 with a processor that has an 
extension to create additional documents.)



Here is an example stylesheet using xsl:result-document to create 
additional documents to be rendered in the iframe. It is an adaption of 
your original stylesheet, you might want to refactor it later based on 
the comments already posted on the list.



<xsl:stylesheet version="2.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/">
<html>
<head>

<style type="text/css">




.linktext {
font-family: Arial;
font-size: 9pt;
font-weight: bold;
color: black;
text-decoration: none
}

a:visited { text-decoration: none }
a:hover { text-decoration:none; color: blue; }
a:active {text-decoration: none; color:red}

.header {
font-family: Arial;
font-size: 12pt;
font-weight: bold
}
</style>

</head>

<body>

<table style="width:100%">

<thead>

<tr>

<th width="40%" class="header">Symptoms</th>

<th width="60%" class="header">Corrective Actions</th>

</tr>

</thead>

<tbody>

<tr>

<td valign="top">

<table border="0">

<xsl:for-each select="fault-knowledge-base/symptoms/symptom">

<xsl:result-document href="{@id}.html">

  <html lang="en">

    <head>

      <title>Actions for symptom <xsl:value-of select="@id"/></title>

    </head>

    <body>

      <ul>

        <xsl:for-each 
select="/fault-knowledge-base/corrective-actions/corrective-action[@id = 
current()/corrective-action-ref/@idref]">

          <li><xsl:value-of select="text"/></li>

        </xsl:for-each>

      </ul>

    </body>

  </html>

</xsl:result-document>

<tr>

<td><a href="{@id}.html" target="I2" class="linktext"><xsl:value-of 
select="text"/></a></td>

</tr>

</xsl:for-each>

</table>

</td>

<td>

<iframe name="I2" marginwidth="3" marginheight="3" height="580" 
width="100%" src="about:blank" align="left" frameborder="0" 
scrolling="auto">

Your browser does not support inline frames or is currently configured 
not to display inline frames.

</iframe>

</td>

</tr>

</tbody>

</table>

</body>

</html>

</xsl:template>

</xsl:stylesheet>




--



	Martin Honnen
	http://JavaScript.FAQTs.com/

>Thread Prev - [xsl] Using XSL to create interactive web page from XML
[Thread Next]

>Archive Index
>xsl-list Archive Home
>Recent entries

Altova Mailing List Archives

Re: [xsl] Using XSL to create interactive web page from XML