Savvoulidis Iordanis wrote:
> How can I convert the following empty tag to zero?
> 
> I want :
> <Coupon>
>    <HomeTeamOdd />
> </Coupon>
> 
> to converted as 
> 
> <Coupon HomeTeamOdd="0">
> </Coupon>

Well what do you want to happen when the HomeTeamOdd element is not empty?
The following stylesheet

<xsl:stylesheet
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   version="1.0">

   <xsl:template match="@* | node()">
     <xsl:copy>
       <xsl:apply-templates select="@* | node()"/>
     </xsl:copy>
   </xsl:template>

   <xsl:template match="Coupon">
     <xsl:copy>
       <xsl:apply-templates select="@*"/>
       <xsl:apply-templates select="HomeTeamOdd"/>
       <xsl:apply-templates select="node()[not(self::HomeTeamOdd)]"/>
     </xsl:copy>
   </xsl:template>

   <xsl:template match="HomeTeamOdd[not(node())]">
     <xsl:attribute name="HomeTeamOdd">0</xsl:attribute>
   </xsl:template>

</xsl:stylesheet>

should do what you want for the input you have shown but somehow your 
problem seems underspecified.


-- 

	Martin Honnen --- MVP XML
	http://msmvps.com/blogs/martin_honnen/