Thank you very much for your answer. We are using saxon9 and will probably 
end up using the first solution (we need to test it first).

Tanks
Vincent

"Martin Honnen" wrote:

> Vincent Lambert wrote:
> 
> > We want to sort the constants in the processing in natural order (in 
> > alphabetical order but with the numbers ordered right, M_AB9 comes before 
> > M_AB10). With the basic sorting, all we can get is alphabetical sorting, but 
> > the numbers are sorted character by character.
> > 
> > Is there anything we can do ?
> 
> Saxon 9 (http://saxon.sourceforge.net/) is an XSLT 2.0 processor where 
> you could do the following:
> 
> <xsl:stylesheet
>    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>    version="2.0">
> 
>    <xsl:output indent="yes"/>
> 
>    <xsl:template match="values-group">
>      <xsl:copy>
>        <xsl:apply-templates select="value">
>          <xsl:sort select="name" 
> collation="http://saxon.sf.net/collation?alphanumeric=yes"/>
>        </xsl:apply-templates>
>      </xsl:copy>
>    </xsl:template>
> 
>    <xsl:template match="@* | node()">
>      <xsl:copy>
>        <xsl:apply-templates select="@* | node()"/>
>      </xsl:copy>
>    </xsl:template>
> 
> </xsl:stylesheet>
> 
> So that stylesheet would simply use a special collation that Saxon 
> supports that splits up the value to be sorted into alphabetical and 
> numerical parts and sorts each part by its own sort rule.
> 
> 
> With an XSLT 1.0 processor like Microsoft's XslCompiledTransform or 
> MSXML you should be able to use the following:
> 
> <xsl:stylesheet
>    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>    version="1.0">
> 
>    <xsl:output indent="yes"/>
> 
>    <xsl:template match="values-group">
>      <xsl:copy>
>        <xsl:apply-templates select="value">
>          <xsl:sort select="substring(name, 1, 4)" data-type="text"/>
>          <xsl:sort select="substring(name, 5)" data-type="number"/>
>        </xsl:apply-templates>
>      </xsl:copy>
>    </xsl:template>
> 
>    <xsl:template match="@* | node()">
>      <xsl:copy>
>        <xsl:apply-templates select="@* | node()"/>
>      </xsl:copy>
>    </xsl:template>
> 
> </xsl:stylesheet>
> 
> That assumes the numbers are always preceeded by four letters.
> 
> -- 
> 
> 	Martin Honnen --- MVP XML
> 	http://msmvps.com/blogs/martin_honnen/
>