M wrote:

> I'm pretty new at xslt. After a lot of research, I come to know my
> question is related to xslt grouping.
> I have an xml file like below with 2 col, with 2 id Word, Excel. Under
> each col is a bunch of row, in this case each col has 3 rows.

Here is an XSLT 1.0 stylesheet:

<xsl:stylesheet
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   version="1.0">

   <xsl:output method="html" indent="yes"/>

   <xsl:param name="lc" select="'abcdefghijklmnopqrstuvwxyz'"/>
   <xsl:param name="uc" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>

   <xsl:template match="templates">
     <table>
       <thead>
         <tr>
           <xsl:apply-templates select="col/@id"/>
         </tr>
       </thead>
       <tbody>
         <xsl:apply-templates select="col[1]/row"/>
       </tbody>
     </table>
   </xsl:template>

   <xsl:template match="col/@id">
     <th>
       <xsl:value-of select="translate(., $lc, $uc)"/>
     </th>
   </xsl:template>

   <xsl:template match="row">
     <xsl:variable name="pos" select="position()"/>
     <tr>
       <xsl:apply-templates select="title | 
../following-sibling::col/row[$pos]/title"/>
     </tr>
   </xsl:template>

   <xsl:template match="title">
     <td>
       <xsl:value-of select="."/>
     </td>
   </xsl:template>

</xsl:stylesheet>



-- 

	Martin Honnen --- MVP XML
	http://JavaScript.FAQTs.com/